home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / GRAPHICS / RAYTRACING / POVRAY3 / POV301 / povray3 / pov3demo / showoff / pov / swirlbox < prev    next >
Text File  |  1995-11-08  |  3KB  |  111 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // File: SwirlBox.POV
  3. // Vers: 3
  4. // Desc: Stacked square rings in a snail shell shape,
  5. //       shows off the use of the while loop for creating objects,
  6. //       and for smoothly changing colors.
  7. // Date: 10/1/95
  8. // Auth: Eduard Schwan
  9.  
  10. #version 3.0
  11. global_settings { assumed_gamma 1.0 }
  12.  
  13. // ------------------------------------------------------------------
  14. // Look down at an angle at our creation
  15. camera
  16. { 
  17.   location  < 4, 9,-20>
  18.   direction  1*z
  19.   look_at   < 0,-1, 8>
  20. } 
  21.  
  22.  
  23. // ------------------------------------------------------------------
  24. // A white marble floor
  25. plane
  26. {
  27.   y, -0.1
  28.   texture
  29.   {
  30.     pigment
  31.     {
  32.       marble
  33.       turbulence 0.5 omega 0.7 rotate -40*y scale 6
  34.       color_map
  35.       {
  36.         [0.50 color rgb 1.0]
  37.         [0.57 color rgb 0.8]
  38.         [0.60 color rgb <0.9,0.8,0.7>]
  39.         [0.63 color rgb 1.0]
  40.       }
  41.     }
  42.     finish {ambient 0.2 reflection 0.3}
  43.   }
  44. }
  45.  
  46.  
  47. // ------------------------------------------------------------------
  48. // Simple background for a simple scene
  49. background { color rgb <0.0, 0.1, 0.2> }
  50.  
  51.  
  52. // ------------------------------------------------------------------
  53. // A light source
  54. light_source { <50, 20, -50> color rgb 1 }
  55.  
  56.  
  57. // ------------------------------------------------------------------
  58. // create a simple square ring shape 
  59. #declare BasicShape = intersection
  60. {
  61.   // flat pizza box
  62.   box { -1, +1 scale <1.0, 0.1, 1.0> }
  63.   // remove square hole in middle
  64.   box { -1, +1 scale <0.95, 1.1, 0.95> inverse }
  65. }
  66.  
  67.  
  68. // ------------------------------------------------------------------
  69. // Set up the loop variables:
  70. // the Counter variable will go from 0.0 to 1.0
  71. // in NumIterations loops.
  72. #declare NumIterations = 80  // try different numbers of boxes (20,40,80...)
  73. // don't change these
  74. #declare Counter       = 0.0
  75. #declare Increment     = 1.0/NumIterations
  76. #declare NumTwists     = 360*2 // two full twists
  77.  
  78.  
  79. // ------------------------------------------------------------------
  80. // Create an iterated object built from our basic shape
  81. union{
  82.   #declare Flipper = 0  // Flipper will switch between 0 and 1 each loop
  83.   #while (Counter<=1.0)
  84.     object
  85.     {
  86.       BasicShape
  87.       // boxes get smaller as we stack them up
  88.       scale <(1-Counter)*5,1,(1-Counter)*5>
  89.       // boxes get closer to center and stack upward as we go
  90.       translate <(1-Counter)*5, Counter*10, 0.0>
  91.       // rotate each box a little more as they stack
  92.       rotate NumTwists*Counter*y
  93.       // put down the texture
  94.       texture
  95.       {
  96.         pigment
  97.         {
  98.           // colors change as we stack them up
  99.           color rgb <1-Counter, Flipper, Counter>
  100.         }
  101.         finish { ambient 0.2 specular 0.7 roughness 0.05 }
  102.       }
  103.     }
  104.     #declare Flipper = 1 - Flipper // flip its value (0->1 or 1->0)
  105.     // manually increment our counter inside the loop
  106.     #declare Counter=Counter+Increment
  107.   #end
  108. }
  109.  
  110.  
  111.